Puppet Class: iptables::service

Defined in:
manifests/service.pp

Overview

Manage the IPTables and IP6Tables services

Parameters:

  • enable (Any) (defaults to: pick(getvar('::iptables::enable'),true))

    Enable IPTables

    • If set to false with disable IPTables completely

    • If set to ignore will stop managing IPTables

  • ipv6 (Any) (defaults to: pick(getvar('::iptables::ipv6'),true))

    Also manage IP6Tables



12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
# File 'manifests/service.pp', line 12

class iptables::service (
  $enable = pick(getvar('::iptables::enable'),true),
  $ipv6   = pick(getvar('::iptables::ipv6'),true)
){
  if $enable != 'ignore' {
    if $enable {
      $_ensure = 'running'
    }
    else {
      $_ensure = 'stopped'
    }

    service { 'iptables':
      ensure     => $_ensure,
      enable     => $enable,
      hasrestart => false,
      restart    => '/sbin/iptables-restore /etc/sysconfig/iptables || ( /sbin/iptables-restore /etc/sysconfig/iptables.bak && exit 3 )',
      hasstatus  => true,
      provider   => 'redhat'
    }

    service { 'iptables-retry':
      enable   => $enable,
      provider => 'redhat'
    }

    if $ipv6 and $facts['ipv6_enabled'] {
      service { 'ip6tables':
        ensure     => $_ensure,
        enable     => $enable,
        hasrestart => false,
        restart    => '/sbin/ip6tables-restore /etc/sysconfig/ip6tables || ( /sbin/ip6tables-restore /etc/sysconfig/ip6tables.bak && exit 3 )',
        hasstatus  => true,
        require    => File['/etc/init.d/ip6tables'],
        provider   => 'redhat'
      }

      service { 'ip6tables-retry':
        enable   => true,
        require  => File['/etc/init.d/ip6tables-retry'],
        provider => 'redhat'
      }
    }

    # firewalld must be disabled on EL7+
    case $::operatingsystem {
      'RedHat','CentOS': {
        if $::operatingsystemmajrelease > '6' {
          service{ 'firewalld':
            ensure => 'stopped',
            enable => false,
            before => Service['iptables']
          }
        }
      }
      default: {
        fail("${::operatingsystem} is not yet supported by ${module_name}")
      }
    }
  }
}